← К каталогу
Исходный код · ID 4849

ORB Ultimate+

indicator orb ultimate+ for tradingview.pine
Вы автор или правообладатель?

Сообщите нам, если считаете, что материал размещён без разрешения.

Краткий обзор

О программе

ORB Ultimate+ — это индикатор-оверлей для TradingView, объединяющий на одном графике несколько инструментов анализа рынка. Он отображает уровни ликвидности более высокого таймфрейма (BSL/SSL), ликвидность торговых сессий (NY AM, NY PM, Asia, London), а также уровни DATA H/L, PWH/PWL. Индикатор включает обнаружение дивергенций SMT с коррелированным инструментом, блоки отторжения на основе пивотов, справедливые ценовые разрывы (FVG) на нескольких таймфреймах и мультитаймфреймный индикатор направления (Bias).

Центральная функция — анализ Opening Range (ORB) с построением диапазона, уровня 50%, зонами заполнения и автоматическим определением триггеров для отработки. При срабатывании условий индикатор отрисовывает на графике уровни входа, стоп-лосс и тейк-профиты, а также оценивает степень подтверждения сделки по шкале.

Поддерживаются пользовательские оповещения TradingView для событий ликвидности сессий и условий входа. Все элементы отрисовки настраиваются индивидуально: цвета, стили линий, размеры меток и видимость групп параметров. Индикатор работает поверх цены на графике и не моделирует торговые операции.

Настройки программы

НастройкаОписание
iHlOn Включает или отключает уровни ликвидности более высокого таймфрейма (BSL/SSL).
iHlBsl Цвет линии уровня BSL (Buy Side Liquidity) более высокого таймфрейма.
iHlSsl Цвет линии уровня SSL (Sell Side Liquidity) более высокого таймфрейма.
iHlTf Таймфрейм для расчёта уровней ликвидности BSL/SSL.
iHlStr Чувствительность обнаружения уровней ликвидности более высокого таймфрейма: Sensitive, Normal или Strict.
iHlSt Стиль линии для уровней BSL/SSL более высокого таймфрейма.
iHlW Толщина линий для уровней BSL/SSL более высокого таймфрейма.
iHlLb Отображает метки для уровней BSL/SSL более высокого таймфрейма.
iHlLbSz Размер меток для уровней BSL/SSL более высокого таймфрейма.
iSlSt Стиль линии для уровней ликвидности сессий.
iSlLbSz Размер меток для уровней ликвидности сессий.
iSlKeep Сохраняет уровни ликвидности сессии на графике после их пробития (митигации).
iAmOn Включает или отключает отображение ликвидности сессии NY AM.
iAmC Цвет отображения ликвидности сессии NY AM.
iAmS Временной диапазон сессии NY AM в формате часами и минутами.
iPmOn Включает или отключает отображение ликвидности сессии NY PM.
iPmC Цвет отображения ликвидности сессии NY PM.
iPmS Временной диапазон сессии NY PM в формате часами и минутами.
iAsOn Включает или отключает отображение ликвидности азиатской сессии.
iAsC Цвет отображения ликвидности азиатской сессии.
iAsS Временной диапазон азиатской сессии в формате часами и минутами.
iLoOn Включает или отключает отображение ликвидности Лондонской сессии.
iLoC Цвет отображения ликвидности Лондонской сессии.
iLoS Временной диапазон Лондонской сессии в формате часами и минутами.
iPdOn Включает или отключает отображение уровней PDH/PDL.
iPdC Цвет отображения уровней PDH/PDL (предыдущий дневной максимум/минимум).
iPwOn Включает или отключает отображение уровней PWH/PWL.
iPwC Цвет отображения уровней PWH/PWL (предыдущий недельный максимум/минимум).
iDtOn Включает или отключает отображение уровней DATA H/L.
iDtC Цвет отображения уровней DATA H/L.
iDtMin Минимальная длина фитиля (в пунктах) для отображения уровня DATA H/L.
iSmMode Режим выбора коррелированного инструмента: автоматический (по умолчанию) или ручной.
iSmSym Символ коррелированного инструмента для расчёта SMT-дивергенций (используется в ручном режиме).
iSmSens Чувствительность обнаружения SMT-дивергенций: Sensitive, Normal или Strict.
iSmMax Максимальное количество одновременно отображаемых SMT-дивергенций на графике.
iSmRt Включает отображение SMT-дивергенций в реальном времени на текущем баре.
iSmGap Включает отображение SMT-дивергенций по разрывам цен (Gap SMT).
iSmSeq Включает последовательные SMT-дивергенции для дополнительных циклов (Micro, 90m, Daily).
iSmBuC Цвет отрисовки бычьих SMT-дивергенций.
iSmBuW Толщина линии для бычьих SMT-дивергенций.
iSmBuSt Стиль линии для бычьих SMT-дивергенций.
iSmBeC Цвет отрисовки медвежьих SMT-дивергенций.
iSmBeW Толщина линии для медвежьих SMT-дивергенций.
iSmBeSt Стиль линии для медвежьих SMT-дивергенций.
iSmLb Отображает метки для SMT-дивергенций.
iSmLbC Цвет меток для SMT-дивергенций.
iSmLbSz Размер меток для SMT-дивергенций.
iSmSymT Отображает название коррелированного инструмента в метках SMT-дивергенций.
iRbOn Включает или отключает отображение блоков отторжения.
iRbBu Цвет отрисовки бычьего блока отторжения.
iRbBe Цвет отрисовки медвежьего блока отторжения.
iRbCe Отображает линию на уровне 50% внутри блока отторжения.
iRbCeSt Стиль линии на уровне 50% внутри блока отторжения.
iRbHtf Проецирует блоки отторжения с более высокого таймфрейма на текущий график.
iRbTf Таймфрейм для проецирования блоков отторжения при включённой опции HTF-проекции.
iRbTfLb Отображает метку таймфрейма на блоках отторжения, проецированных с HTF.
iOrOn Включает или отключает отображение Opening Range (ORB).
iOrLen Длительность диапазона открытия (ORB): 15 минут или 5 минут.
iOrAs Включает азиатский диапазон открытия (ORB) в дополнение к основному.
iOrLo Включает Лондонский диапазон открытия (ORB) в дополнение к основному.
iOrFill Цвет заливки зоны Opening Range (ORB).
iOrHc Цвет метки и линии верхнего уровня Opening Range (ORH).
iOrMc Цвет метки и линии среднего уровня Opening Range (50%).
iOrLc Цвет метки и линии нижнего уровня Opening Range (ORL).
iOrLnC Цвет линий Opening Range (верхняя, средняя, нижняя).
iOrSt Стиль линий Opening Range (сплошная, пунктирная, точечная).
iOrW Толщина линий Opening Range.
iOrLb Отображает метки для уровней Opening Range.
iOrLbSz Размер меток для уровней Opening Range.
iOrPx Отображает числовые значения цен рядом с метками Opening Range.
iOrNoon Удаляет уровни ORB после 12:00 по восточному времени.
iFvOn Включает или отключает отображение справедливых ценовых разрывов (FVG).
iFv1On Включает или отключает первый уровень справедливых ценовых разрывов (FVG).
iFv1 Таймфрейм для первого уровня справедливых ценовых разрывов (FVG).
iFv2On Включает или отключает второй уровень справедливых ценовых разрывов (FVG).
iFv2 Таймфрейм для второго уровня справедливых ценовых разрывов (FVG).
iFv3On Включает или отключает третий уровень справедливых ценовых разрывов (FVG).
iFv3 Таймфрейм для третьего уровня справедливых ценовых разрывов (FVG).
iFvBu Цвет отрисовки бычьих справедливых ценовых разрывов (FVG).
iFvBe Цвет отрисовки медвежьих справедливых ценовых разрывов (FVG).
iFvBrd Отображает границу вокруг блоков справедливых ценовых разрывов (FVG).
iFvCe Отображает линию на уровне 50% внутри блока справедливого ценового разрыва (FVG).
iFvCeSt Стиль линии на уровне 50% внутри блока FVG.
iFvLbC Цвет меток для блоков справедливых ценовых разрывов (FVG).
iFvLbSz Размер меток для блоков справедливых ценовых разрывов (FVG).
iFvMin Минимальный размер разрыва (в пунктах) для отображения блока FVG.
iB1On Включает или отключает первый уровень индикатора направления (Bias).
iB1 Таймфрейм для первого уровня индикатора направления (Bias).
iB2On Включает или отключает второй уровень индикатора направления (Bias).
iB2 Таймфрейм для второго уровня индикатора направления (Bias).
iB3On Включает или отключает третий уровень индикатора направления (Bias).
iB3 Таймфрейм для третьего уровня индикатора направления (Bias).
iB4On Включает или отключает четвёртый уровень индикатора направления (Bias).
iB4 Таймфрейм для четвёртого уровня индикатора направления (Bias).
iBiTbl Отображает таблицу мультитаймфреймного индикатора направления (Bias) на графике.
iFkOn Включает или отключает маркировку ложного пробоя ORB.
iFkC Цвет метки для маркировки ложного пробоя ORB.
iCwOn Включает или отключает автоматический триггер CW (отработку).
iCwBu Цвет отрисовки бычьего триггера CW (отработка вверх).
iCwBe Цвет отрисовки медвежьего триггера CW (отработка вниз).

Поиск по коду файла

indicator("ORB Ultimate+", shorttitle = "ORB Ultimate+", overlay = true, max_lines_count = 500, max_labels_count = 500, max_boxes_count = 500, max_bars_back = 1000)
const string TZ    = "America/New_York"
const string G_HL  = "HTF Liquidity"
const string G_SL  = "Session Liquidity"
const string G_SMT = "SMT Divergence"
const string G_RB  = "Rejection Blocks"
const string G_OR  = "Opening Range"
const string G_FV  = "HTF Fair Value Gaps"
const string G_BI  = "HTF Bias"
const string G_AL  = "Alerts"
const int    CW_WIN   = 10
const int    GRADE_MS = 60 * 60 * 1000
const int    SMT_SPAN = 120
bool   iHlOn   = input.bool(true, "Enable", group = G_HL)
color  iHlBsl  = input.color(#787B86, "BSL", inline = "hc", group = G_HL)
color  iHlSsl  = input.color(#787B86, "SSL", inline = "hc", group = G_HL)
string iHlTf   = input.timeframe("60", "Timeframe", group = G_HL)
string iHlStr  = input.string("Normal", "Strictness", options = ["Sensitive", "Normal", "Strict"], group = G_HL)
string iHlSt   = input.string("Dotted", "Line style", options = ["Solid", "Dashed", "Dotted"], inline = "hs", group = G_HL)
int    iHlW    = input.int(1, "Width", minval = 1, maxval = 4, inline = "hs", group = G_HL)
bool   iHlLb   = input.bool(true, "Labels", inline = "hl", group = G_HL)
string iHlLbSz = input.string("Tiny", "", options = ["Tiny", "Small", "Normal", "Large", "Huge"], inline = "hl", group = G_HL)
string iSlSt   = input.string("Dotted", "Line style", options = ["Solid", "Dashed", "Dotted"], group = G_SL)
string iSlLbSz = input.string("Tiny", "Label size", options = ["Tiny", "Small", "Normal", "Large", "Huge"], group = G_SL)
bool   iSlKeep = input.bool(false, "Preserve After Mitigation", group = G_SL)
bool   iAmOn   = input.bool(true, "NY AM", inline = "am", group = G_SL)
color  iAmC    = input.color(#787B86, "", inline = "am", group = G_SL)
string iAmS    = input.session("0930-1100", "", inline = "am", group = G_SL)
bool   iPmOn   = input.bool(true, "NY PM", inline = "pm", group = G_SL)
color  iPmC    = input.color(#787B86, "", inline = "pm", group = G_SL)
string iPmS    = input.session("1330-1600", "", inline = "pm", group = G_SL)
bool   iAsOn   = input.bool(true, "Asia", inline = "as", group = G_SL)
color  iAsC    = input.color(#787B86, "", inline = "as", group = G_SL)
string iAsS    = input.session("2000-0000", "", inline = "as", group = G_SL)
bool   iLoOn   = input.bool(true, "London", inline = "lo", group = G_SL)
color  iLoC    = input.color(#787B86, "", inline = "lo", group = G_SL)
string iLoS    = input.session("0200-0500", "", inline = "lo", group = G_SL)
bool   iPdOn   = input.bool(true, "PDH / PDL", inline = "pd", group = G_SL)
color  iPdC    = input.color(#787B86, "", inline = "pd", group = G_SL)
bool   iPwOn   = input.bool(true, "PWH / PWL", inline = "pw", group = G_SL)
color  iPwC    = input.color(#787B86, "", inline = "pw", group = G_SL)
bool   iDtOn   = input.bool(true, "DATA H / L", inline = "dt", group = G_SL)
color  iDtC    = input.color(#787B86, "", inline = "dt", group = G_SL)
float  iDtMin  = input.float(10.0, "Min wick (pts)", minval = 0, step = 0.25, inline = "dt", group = G_SL)
string iSmMode = input.string("Automatic", "Correlated asset", options = ["Automatic", "Manual"], inline = "sm", group = G_SMT)
string iSmSym  = input.symbol("CME_MINI:ES1!", "", inline = "sm", group = G_SMT)
string iSmSens = input.string("Normal", "Sensitivity", options = ["Sensitive", "Normal", "Strict"], group = G_SMT)
int    iSmMax  = input.int(5, "Max visible", minval = 1, maxval = 50, group = G_SMT)
bool   iSmRt   = input.bool(false, "Real-time SMTs", group = G_SMT)
bool   iSmGap  = input.bool(false, "Gap SMTs", group = G_SMT)
bool   iSmSeq  = input.bool(false, "Sequential SMTs", group = G_SMT)
color  iSmBuC  = input.color(#5D606B, "Bullish", inline = "sb", group = G_SMT)
int    iSmBuW  = input.int(1, "", minval = 1, maxval = 4, inline = "sb", group = G_SMT)
string iSmBuSt = input.string("Solid", "", options = ["Solid", "Dashed", "Dotted"], inline = "sb", group = G_SMT)
color  iSmBeC  = input.color(#5D606B, "Bearish", inline = "se", group = G_SMT)
int    iSmBeW  = input.int(1, "", minval = 1, maxval = 4, inline = "se", group = G_SMT)
string iSmBeSt = input.string("Solid", "", options = ["Solid", "Dashed", "Dotted"], inline = "se", group = G_SMT)
bool   iSmLb   = input.bool(true, "Labels", inline = "sl", group = G_SMT)
color  iSmLbC  = input.color(#5D606B, "", inline = "sl", group = G_SMT)
string iSmLbSz = input.string("Tiny", "", options = ["Tiny", "Small", "Normal", "Large", "Huge"], inline = "sl", group = G_SMT)
bool   iSmSymT = input.bool(true, "Show symbol", inline = "sl", group = G_SMT)
bool   iRbOn   = input.bool(true, "Enable", group = G_RB)
color  iRbBu   = input.color(color.new(#089981, 82), "Bullish", inline = "rc", group = G_RB)
color  iRbBe   = input.color(color.new(#F23645, 82), "Bearish", inline = "rc", group = G_RB)
bool   iRbCe   = input.bool(true, "50% (CE) line", inline = "rce", group = G_RB)
string iRbCeSt = input.string("Dashed", "", options = ["Solid", "Dashed", "Dotted"], inline = "rce", group = G_RB)
bool   iRbHtf  = input.bool(false, "Project from HTF", inline = "rh", group = G_RB)
string iRbTf   = input.timeframe("15", "", inline = "rh", group = G_RB)
bool   iRbTfLb = input.bool(true, "HTF box timeframe label", group = G_RB)
bool   iOrOn   = input.bool(true, "Enable", group = G_OR)
string iOrLen  = input.string("15m", "Range", options = ["15m", "5m"], group = G_OR)
bool   iOrAs   = input.bool(false, "Asia ORB", inline = "ox", group = G_OR)
bool   iOrLo   = input.bool(false, "London ORB", inline = "ox", group = G_OR)
color  iOrFill = input.color(color.new(#2962FF, 88), "Fill", group = G_OR)
color  iOrHc   = input.color(#089981, "High", inline = "oc", group = G_OR)
color  iOrMc   = input.color(#787B86, "50%", inline = "oc", group = G_OR)
color  iOrLc   = input.color(#F23645, "Low", inline = "oc", group = G_OR)
color  iOrLnC  = input.color(#434651, "Line", inline = "ol", group = G_OR)
string iOrSt   = input.string("Solid", "", options = ["Solid", "Dashed", "Dotted"], inline = "ol", group = G_OR)
int    iOrW    = input.int(1, "", minval = 1, maxval = 4, inline = "ol", group = G_OR)
bool   iOrLb   = input.bool(true, "Labels", inline = "olb", group = G_OR)
string iOrLbSz = input.string("Tiny", "", options = ["Tiny", "Small", "Normal", "Large", "Huge"], inline = "olb", group = G_OR)
bool   iOrPx   = input.bool(false, "Show prices", inline = "olb", group = G_OR)
bool   iOrNoon = input.bool(true, "Remove ORB after 12:00 ET", group = G_OR)
bool   iFvOn   = input.bool(true, "Enable", group = G_FV)
bool   iFv1On  = input.bool(true, "", inline = "f1", group = G_FV)
string iFv1    = input.timeframe("15", "", inline = "f1", group = G_FV)
bool   iFv2On  = input.bool(true, "", inline = "f1", group = G_FV)
string iFv2    = input.timeframe("60", "", inline = "f1", group = G_FV)
bool   iFv3On  = input.bool(true, "", inline = "f1", group = G_FV)
string iFv3    = input.timeframe("240", "", inline = "f1", group = G_FV)
color  iFvBu   = input.color(color.new(#089981, 75), "Bullish", inline = "fc", group = G_FV)
color  iFvBe   = input.color(color.new(#F23645, 75), "Bearish", inline = "fc", group = G_FV)
bool   iFvBrd  = input.bool(false, "Border", group = G_FV)
bool   iFvCe   = input.bool(false, "50% (CE) line", inline = "fce", group = G_FV)
string iFvCeSt = input.string("Dashed", "", options = ["Solid", "Dashed", "Dotted"], inline = "fce", group = G_FV)
color  iFvLbC  = input.color(#434651, "Label", inline = "fl", group = G_FV)
string iFvLbSz = input.string("Tiny", "", options = ["Tiny", "Small", "Normal", "Large", "Huge"], inline = "fl", group = G_FV)
float  iFvMin  = input.float(0.0, "Min gap size (pts)", minval = 0, step = 0.25, group = G_FV)
bool   iB1On   = input.bool(true, "", inline = "b1", group = G_BI)
string iB1     = input.timeframe("W", "", inline = "b1", group = G_BI)
bool   iB2On   = input.bool(true, "", inline = "b1", group = G_BI)
string iB2     = input.timeframe("D", "", inline = "b1", group = G_BI)
bool   iB3On   = input.bool(true, "", inline = "b2", group = G_BI)
string iB3     = input.timeframe("240", "", inline = "b2", group = G_BI)
bool   iB4On   = input.bool(true, "", inline = "b2", group = G_BI)
string iB4     = input.timeframe("60", "", inline = "b2", group = G_BI)
bool   iBiTbl  = input.bool(true, "Bias table", group = G_BI)
bool   iFkOn   = input.bool(true, "ORB Fakeout", inline = "fk", group = G_BI)
color  iFkC    = input.color(#787B86, "", inline = "fk", group = G_BI)
bool   iCwOn   = input.bool(true, "CW Trigger", inline = "cw", group = G_BI)
color  iCwBu   = input.color(#089981, "", inline = "cw", group = G_BI)
color  iCwBe   = input.color(#F23645, "", inline = "cw", group = G_BI)
bool   iLim    = input.bool(true, "Limit lines (SL / BE / TP)", group = G_BI)
color  iSlC    = input.color(#F23645, "SL", inline = "lc", group = G_BI)
color  iBeC    = input.color(#FF9800, "BE", inline = "lc", group = G_BI)
color  iTpC    = input.color(#089981, "TP", inline = "lc", group = G_BI)
bool   iMinRR  = input.bool(true, "Min RR for TP levels", group = G_BI)
bool   iChk    = input.bool(true, "Setup Checklist", group = G_BI)
bool   iAlSw   = input.bool(true, "Session liquidity sweep", group = G_AL)
bool   iAlCw   = input.bool(true, "CW entry", group = G_AL)
bool   iAw1On  = input.bool(true, "Window 1", inline = "a1", group = G_AL)
string iAw1    = input.session("0930-1200", "", inline = "a1", group = G_AL)
bool   iAw2On  = input.bool(false, "Window 2", inline = "a2", group = G_AL)
string iAw2    = input.session("1330-1600", "", inline = "a2", group = G_AL)
bool   iAw3On  = input.bool(false, "Window 3", inline = "a3", group = G_AL)
string iAw3    = input.session("0200-0500", "", inline = "a3", group = G_AL)
f_st(string s) => s == "Dashed" ? line.style_dashed : s == "Dotted" ? line.style_dotted : line.style_solid
f_sz(string s) => s == "Small" ? size.small : s == "Normal" ? size.normal : s == "Large" ? size.large : s == "Huge" ? size.huge : size.tiny
f_in(string s) => not na(time(timeframe.period, s + ":1234567", TZ))
f_hm(string s, int o) => int(str.tonumber(str.substring(s, o, o + 2))) * 60 + int(str.tonumber(str.substring(s, o + 2, o + 4)))
f_px(float x) => str.tostring(x, format.mintick)
f_tfLong(string tf) =>
    int s = timeframe.in_seconds(tf)
    s >= 2419200 ? "Monthly" : s >= 604800 ? "Weekly" : s >= 86400 ? "Daily" : s >= 3600 ? str.tostring(s / 3600) + "H" : str.tostring(s / 60) + "m"
f_tfShort(string tf) =>
    int s = timeframe.in_seconds(tf)
    s >= 2419200 ? "MN" : s >= 604800 ? "W1" : s >= 86400 ? "D1" : s >= 3600 ? "H" + str.tostring(s / 3600) : "M" + str.tostring(s / 60)
f_grade(int n) => n >= 4 ? "A+" : n == 3 ? "A" : n == 2 ? "B" : n == 1 ? "C" : "D"
int tfSec = timeframe.in_seconds()
int tfMs  = tfSec * 1000
int rx    = time + 3 * tfMs
var array<int> tsSmt = array.from(0, 0)
var array<int> tsRb  = array.from(0, 0)
var array<int> tsFvg = array.from(0, 0)
var array<int> tsSwp = array.from(0, 0)
f_recent(array<int> a, int d) =>
    int t = a.get(d == 1 ? 0 : 1)
    t > 0 and t >= time - GRADE_MS
f_bias() =>
    var int   st = 0
    var float sh = na
    var float sl = na
    float ph = ta.pivothigh(high, 2, 2)
    float pl = ta.pivotlow(low, 2, 2)
    if not na(ph)
        sh := ph
    if not na(pl)
        sl := pl
    if not na(sh) and close > sh
        st := 1
        sh := na
    if not na(sl) and close < sl
        st := -1
        sl := na
    st[1]
int bs1 = request.security(syminfo.tickerid, iB1, f_bias(), lookahead = barmerge.lookahead_on)
int bs2 = request.security(syminfo.tickerid, iB2, f_bias(), lookahead = barmerge.lookahead_on)
int bs3 = request.security(syminfo.tickerid, iB3, f_bias(), lookahead = barmerge.lookahead_on)
int bs4 = request.security(syminfo.tickerid, iB4, f_bias(), lookahead = barmerge.lookahead_on)
int nBu = (iB1On and nz(bs1) == 1 ? 1 : 0) + (iB2On and nz(bs2) == 1 ? 1 : 0) + (iB3On and nz(bs3) == 1 ? 1 : 0) + (iB4On and nz(bs4) == 1 ? 1 : 0)
int nBe = (iB1On and nz(bs1) == -1 ? 1 : 0) + (iB2On and nz(bs2) == -1 ? 1 : 0) + (iB3On and nz(bs3) == -1 ? 1 : 0) + (iB4On and nz(bs4) == -1 ? 1 : 0)
int bias = nBu > nBe ? 1 : nBe > nBu ? -1 : 0
type Lvl
    float  y
    int    t
    int    side
    int    kind
    line   ln
    label  lb
    string txt
var array<Lvl> lvls = array.new<Lvl>()
f_lvlC(int k, int side) =>
    switch k
        0 => side == 1 ? iHlBsl : iHlSsl
        1 => iAmC
        2 => iPmC
        3 => iAsC
        4 => iLoC
        5 => iPdC
        6 => iPwC
        => iDtC
f_addLvl(float y, int t, int side, int k, string txt) =>
    color c  = f_lvlC(k, side)
    bool  hl = k == 0
    line  ln = line.new(t, y, rx, y, xloc.bar_time, color = c, style = f_st(hl ? iHlSt : iSlSt), width = hl ? iHlW : 1)
    label lb = (not hl or iHlLb) ? label.new(rx, y, txt, xloc.bar_time, color = color(na), textcolor = c, style = label.style_label_left, size = f_sz(hl ? iHlLbSz : iSlLbSz)) : na
    lvls.push(Lvl.new(y, t, side, k, ln, lb, txt))
f_dropKind(int k) =>
    if lvls.size() > 0
        for i = lvls.size() - 1 to 0
            Lvl l = lvls.get(i)
            if l.kind == k
                l.ln.delete()
                l.lb.delete()
                lvls.remove(i)
f_cap(int k, int side, int mx) =>
    int n = 0
    if lvls.size() > 0
        for i = lvls.size() - 1 to 0
            Lvl l = lvls.get(i)
            if l.kind == k and l.side == side
                n += 1
                if n > mx
                    l.ln.delete()
                    l.lb.delete()
                    lvls.remove(i)
bool sesShow = timeframe.isintraday and tfSec < 14400
bool pdShow  = timeframe.isintraday
bool pwShow  = tfSec < 604800
bool hlShow  = iHlOn and timeframe.in_seconds(iHlTf) > tfSec
bool dtShow  = iDtOn and tfSec >= 60 and tfSec < 3600
int hlN = iHlStr == "Sensitive" ? 1 : iHlStr == "Strict" ? 3 : 2
f_piv(int n) =>
    float ph = ta.pivothigh(high, n, n)
    float pl = ta.pivotlow(low, n, n)
    [ph[1], pl[1], time[n + 1], time]
[hlPh, hlPl, hlPt, hlT] = request.security(syminfo.tickerid, iHlTf, f_piv(hlN), lookahead = barmerge.lookahead_on)
if hlShow and hlT != hlT[1]
    if not na(hlPh)
        f_addLvl(hlPh, hlPt, 1, 0, "BSL")
        f_cap(0, 1, 10)
    if not na(hlPl)
        f_addLvl(hlPl, hlPt, -1, 0, "SSL")
        f_cap(0, -1, 10)
type Ses
    float h  = na
    float l  = na
    int   hT = 0
    int   lT = 0
method track(Ses s, bool inS, bool st) =>
    if st
        s.h  := high
        s.l  := low
        s.hT := time
        s.lT := time
    else if inS
        if high > s.h
            s.h  := high
            s.hT := time
        if low < s.l
            s.l  := low
            s.lT := time
    s
f_sesEnd(Ses s, int k, string nm) =>
    if not na(s.h)
        f_dropKind(k)
        f_addLvl(s.h, s.hT, 1, k, nm + " H")
        f_addLvl(s.l, s.lT, -1, k, nm + " L")
var Ses sAm = Ses.new()
var Ses sPm = Ses.new()
var Ses sAs = Ses.new()
var Ses sLo = Ses.new()
bool inAm = f_in(iAmS)
bool inPm = f_in(iPmS)
bool inAs = f_in(iAsS)
bool inLo = f_in(iLoS)
sAm.track(inAm, inAm and not inAm[1])
sPm.track(inPm, inPm and not inPm[1])
sAs.track(inAs, inAs and not inAs[1])
sLo.track(inLo, inLo and not inLo[1])
if sesShow
    if iAmOn and not inAm and inAm[1]
        f_sesEnd(sAm, 1, "NY AM")
    if iPmOn and not inPm and inPm[1]
        f_sesEnd(sPm, 2, "NY PM")
    if iAsOn and not inAs and inAs[1]
        f_sesEnd(sAs, 3, "Asia")
    if iLoOn and not inLo and inLo[1]
        f_sesEnd(sLo, 4, "London")
[pdH, pdL, pdT] = request.security(syminfo.tickerid, "D", [high[1], low[1], time], lookahead = barmerge.lookahead_on)
[pwH, pwL, pwT] = request.security(syminfo.tickerid, "W", [high[1], low[1], time], lookahead = barmerge.lookahead_on)
if iPdOn and pdShow and pdT != pdT[1] and not na(pdH)
    f_dropKind(5)
    f_addLvl(pdH, pdT, 1, 5, "PDH")
    f_addLvl(pdL, pdT, -1, 5, "PDL")
if iPwOn and pwShow and pwT != pwT[1] and not na(pwH)
    f_dropKind(6)
    f_addLvl(pwH, pwT, 1, 6, "PWH")
    f_addLvl(pwL, pwT, -1, 6, "PWL")
string dtTf = tfSec < 60 ? timeframe.period : "1"
[dtT, dtH, dtL, dtO, dtC] = request.security_lower_tf(syminfo.tickerid, dtTf, [time, high, low, open, close])
if dtShow and dtT.size() > 0
    for i = 0 to dtT.size() - 1
        int tt = dtT.get(i)
        if hour(tt, TZ) == 8 and minute(tt, TZ) == 30
            float uw = dtH.get(i) - math.max(dtO.get(i), dtC.get(i))
            float lw = math.min(dtO.get(i), dtC.get(i)) - dtL.get(i)
            if uw >= iDtMin or lw >= iDtMin
                f_dropKind(7)
            if uw >= iDtMin
                f_addLvl(dtH.get(i), tt, 1, 7, "DATA H")
            if lw >= iDtMin
                f_addLvl(dtL.get(i), tt, -1, 7, "DATA L")
bool   swHit = false
string swTxt = ""
if lvls.size() > 0
    for i = lvls.size() - 1 to 0
        Lvl l = lvls.get(i)
        if l.t < time and (l.side == 1 ? high > l.y : low < l.y)
            tsSwp.set(l.side == 1 ? 1 : 0, time)
            if l.kind > 0
                swHit := true
                swTxt := swTxt + (swTxt == "" ? "" : ", ") + l.txt
            if iSlKeep and l.kind > 0
                l.ln.set_x2(time)
                if not na(l.lb)
                    l.lb.set_x(time)
            else
                l.ln.delete()
                l.lb.delete()
            lvls.remove(i)
string pairSym = switch syminfo.root
    "NQ"  => "CME_MINI:ES1!"
    "ES"  => "CME_MINI:NQ1!"
    "MNQ" => "CME_MINI:MES1!"
    "MES" => "CME_MINI:MNQ1!"
    "YM"  => "CME_MINI:ES1!"
    "MYM" => "CME_MINI:MES1!"
    "GC"  => "COMEX:SI1!"
    "SI"  => "COMEX:GC1!"
    "MGC" => "COMEX:SIL1!"
    "SIL" => "COMEX:MGC1!"
    => iSmSym
string smtSym = iSmMode == "Automatic" ? pairSym : iSmSym
array<string> smtParts = str.split(smtSym, ":")
string pairNm = str.upper(str.replace_all(str.replace_all(smtParts.get(smtParts.size() - 1), "1!", ""), "2!", ""))
f_pair() => [time, high, low, low > high[2], high < low[2]]
[pT, pH, pL, pFb, pFs] = request.security(ticker.inherit(syminfo.tickerid, smtSym), timeframe.period, f_pair(), gaps = barmerge.gaps_on, ignore_invalid_symbol = true)
bool smOn = timeframe.isintraday
bool pOk  = smOn and not na(pT) and pT == time
var float fH = na
var float fL = na
if pOk
    fH := pH
    fL := pL
type SmtD
    line  ln
    label lb
var array<SmtD> smts = array.new<SmtD>()
f_smtDraw(int d, int x1, float y1, int x2, float y2, string tag) =>
    color  c  = d == 1 ? iSmBuC : iSmBeC
    line   ln = line.new(x1, y1, x2, y2, xloc.bar_time, color = c, width = d == 1 ? iSmBuW : iSmBeW, style = f_st(d == 1 ? iSmBuSt : iSmBeSt))
    string tx = tag + (iSmSymT ? " w/ " + pairNm : "")
    label  lb = iSmLb ? label.new(x2, y2, tx, xloc.bar_time, color = color(na), textcolor = iSmLbC, style = d == 1 ? label.style_label_up : label.style_label_down, size = f_sz(iSmLbSz)) : na
    smts.push(SmtD.new(ln, lb))
    if smts.size() > iSmMax
        SmtD o = smts.shift()
        o.ln.delete()
        o.lb.delete()
int   smN   = iSmSens == "Sensitive" ? 1 : iSmSens == "Strict" ? 6 : 4
float cPh   = ta.pivothigh(high, smN, smN)
float cPl   = ta.pivotlow(low, smN, smN)
float pWinH = ta.highest(fH, 2 * smN + 1)
float pWinL = ta.lowest(fL, 2 * smN + 1)
int   pvT   = time[smN]
var float lPh   = na
var float lPph  = na
var int   lPhT  = 0
var int   lPhBi = 0
var float lPl   = na
var float lPpl  = na
var int   lPlT  = 0
var int   lPlBi = 0
if smOn and not na(cPh)
    if not na(lPh) and not na(lPph) and not na(pWinH) and bar_index - smN - lPhBi <= SMT_SPAN
        if (cPh > lPh and pWinH <= lPph) or (cPh < lPh and pWinH > lPph)
            tsSmt.set(1, time)
            f_smtDraw(-1, lPhT, lPh, pvT, cPh, "SMT")
    lPh   := cPh
    lPph  := pWinH
    lPhT  := pvT
    lPhBi := bar_index - smN
if smOn and not na(cPl)
    if not na(lPl) and not na(lPpl) and not na(pWinL) and bar_index - smN - lPlBi <= SMT_SPAN
        if (cPl < lPl and pWinL >= lPpl) or (cPl > lPl and pWinL < lPpl)
            tsSmt.set(0, time)
            f_smtDraw(1, lPlT, lPl, pvT, cPl, "SMT")
    lPl   := cPl
    lPpl  := pWinL
    lPlT  := pvT
    lPlBi := bar_index - smN
var line  rtBuL = na
var line  rtBeL = na
var label rtBuB = na
var label rtBeB = na
if barstate.islast
    rtBuL.delete()
    rtBeL.delete()
    rtBuB.delete()
    rtBeB.delete()
    if iSmRt and pOk
        if not na(lPl) and not na(lPpl) and ((low < lPl and pL >= lPpl) or (low > lPl and pL < lPpl))
            rtBuL := line.new(lPlT, lPl, time, low, xloc.bar_time, color = iSmBuC, width = iSmBuW, style = line.style_dashed)
            rtBuB := iSmLb ? label.new(time, low, "SMT" + (iSmSymT ? " w/ " + pairNm : ""), xloc.bar_time, color = color(na), textcolor = iSmLbC, style = label.style_label_up, size = f_sz(iSmLbSz)) : na
        if not na(lPh) and not na(lPph) and ((high > lPh and pH <= lPph) or (high < lPh and pH > lPph))
            rtBeL := line.new(lPhT, lPh, time, high, xloc.bar_time, color = iSmBeC, width = iSmBeW, style = line.style_dashed)
            rtBeB := iSmLb ? label.new(time, high, "SMT" + (iSmSymT ? " w/ " + pairNm : ""), xloc.bar_time, color = color(na), textcolor = iSmLbC, style = label.style_label_down, size = f_sz(iSmLbSz)) : na
bool cFb = low > high[2]
bool cFs = high < low[2]
if iSmGap and pOk
    if cFb != pFb
        tsSmt.set(0, time)
        f_smtDraw(1, time[2], low[2], time, low, "Gap SMT")
    if cFs != pFs
        tsSmt.set(1, time)
        f_smtDraw(-1, time[2], high[2], time, high, "Gap SMT")
type QCyc
    int    lenS
    string nm
    int    id  = -1
    float  h   = na
    float  l   = na
    int    hT  = 0
    int    lT  = 0
    float  qh  = na
    float  

Показано первые 50% кода (символов: 30889)